Windows11设置快捷方式小箭头

@Ta 01-16 13:27发布,01-16 13:30修改 659点击

Windows11设置快捷方式小箭头

  1. 知根知底才敢用,该脚本无毒无公害

    自动提权,不放心可以不用,删掉这段,然后鼠标右键用管理员身份执行bat效果也一样的

    if exist "%SystemRoot%\SysWOW64" path %path%;%windir%\SysNative;%SystemRoot%\SysWOW64;%~dp0
    bcdedit >nul
    if '%errorlevel%' NEQ '0' (goto UACPrompt) else (goto UACAdmin)
    :UACPrompt
    %1 start "" mshta vbscript:createobject("shell.application").shellexecute("""%~0""","::",,"runas",1)(window.close)&exit
    exit /B
    :UACAdmin
    cd /d "%~dp0"
    

    根据用户输入,走不同的逻辑分支

    :init
    echo. 1、取消Windows 11 快捷方式的小箭头
    echo. 2、恢复Windows 11 快捷方式的小箭头
    set /p input=请选择(1-2)回车: 
    
    if "%input%" GEQ "3" (
    echo. 没有这个选项,请重新选择!(退出?请关闭窗口)
    	goto :init
    ) else (
        goto :execute%input%
    )
    exit
    

    取消跟恢复这两段代码几乎一样,区别在于value值,前者是197后者是154,是新增或者修改注册表操作,介意的话勿用。你甚至可以单独复制命令用cmd执行,而不需要该执行脚本。

    :execute1
    echo.
    echo 取消中...
    echo.
    REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Icons" /v 29 /d "%systemroot%\system32\imageres.dll,197" /t REG_SZ /f
    echo.
    set /p input2=重启资源管理器?(y:重启/任意键:不重启)回车: 
    if "%input2%" EQU "y" (
    	goto :reboot
    ) else (
    	exit
    )
    
    :execute2
    echo.
    echo 恢复中...
    echo.
    REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Icons" /v 29 /d "%systemroot%\system32\imageres.dll,154" /t REG_SZ /f
    echo.
    set /p input2=重启资源管理器?(y:重启/任意键:不重启)回车: 
    if "%input2%" EQU "y" (
    	goto :reboot
    ) else (
    	exit
    )
    

    重启资源管理器或者自己手动重启电脑才会生效

    :reboot
    echo.
    echo. 重启资源管理器...
    taskkill /f /im explorer.exe
    start explorer
    exit
    
  2. 附件和截图

    Windows11设置快捷方式小箭头.bat(2 KB)
    image.png(112.55 KB)

回复列表(1)
  • @Ta / 01-16 13:32 / /
    测试环境:
    image.png(26.17 KB)
    不是对任何系统都有效的,如果不生效,重新执行一遍,恢复即可!
添加新回复
回复需要登录